@echo off
REM ================================================================
REM Vollstaendiger PDF-Build der Fortna-Dokumentation (DE)
REM
REM Ablauf:
REM   1. index.rst aus vorhandenen chapters/**/*.de.rst generieren
REM   2. sphinx-build -b latex  -> _build/latex/*.tex
REM   3. lualatex (via latexmk) -> _build/latex/Fortna_Dokumentation_DE.pdf
REM
REM Voraussetzung: chapters/ ist befuellt (fortna_convert_chapters.bat --apply)
REM ================================================================

call "%~dp0setenv.bat"

if not exist "%PROJECT%\.venv" (
    echo FEHLER: .venv nicht gefunden. Bitte zuerst install_py.bat ausfuehren.
    exit /b 1
)

call "%PROJECT%\.venv\Scripts\activate.bat"

echo.
echo [1/3] index.rst generieren ...
python "%PV_LIB%\build_index.py"

echo.
echo [2/3] LaTeX-Quellen erzeugen (sphinx-build -b latex) ...
python -m sphinx -b latex "%PROJECT%" "%PROJECT%\_build\latex"

echo.
echo [3/3] PDF erzeugen (lualatex) ...
pushd "%PROJECT%\_build\latex"
latexmk -lualatex -interaction=nonstopmode Fortna_Dokumentation_DE.tex
popd

echo.
echo Fertig. PDF: %PROJECT%\_build\latex\Fortna_Dokumentation_DE.pdf
deactivate