@echo off
REM ================================================================
REM DXFMAKROS - Export-CSV als Boundingbox-Draufsicht (SVG) anzeigen
REM ================================================================
REM Zeichnet jede Zeile der Export-CSV (EXPORTCSV) als achsparalleles
REM Rechteck aus Position + Boundingbox, mit Legende und Tooltip je
REM Rechteck sowie den Anschluss-Koordinatensystemen K1-K4 (rotes Kreuz,
REM blaue Linie K1->K2->K3->K4), und oeffnet das Ergebnis im Browser.
REM
REM Die Darstellung uebernimmt sps_skel (bin\material_flow.bat,
REM Option --show-bbs). sps_skel wird neben dxfmakros erwartet
REM (..\sps_skel) oder ueber die Umgebungsvariable SPS_SKEL_HOME.
REM
REM Aufruf:
REM   bin\show_exportcsv.bat                     results\export.csv, alle Zeilen
REM   bin\show_exportcsv.bat meine_export.csv    andere CSV in results\ (oder Pfad)
REM   bin\show_exportcsv.bat export.csv flow     ohne VF/GF-Einzelbausteine
REM
REM Ergebnis: %SKEL_RESULTS%\<name>_bbs.svg
REM ================================================================

setlocal

REM Umgebung dxfmakros (DXFM_RESULTS ...)
call "%~dp0setenv.bat" >nul

REM sps_skel suchen
if not defined SPS_SKEL_HOME set "SPS_SKEL_HOME=%DXFMAKRO%\..\sps_skel"
if not exist "%SPS_SKEL_HOME%\bin\material_flow.bat" (
    echo FEHLER: sps_skel nicht gefunden: %SPS_SKEL_HOME%
    echo         SPS_SKEL_HOME auf den sps_skel-Ordner setzen.
    endlocal & exit /b 1
)

REM Umgebung sps_skel (SKEL_RESULTS ...) - material_flow.bat ruft setenv
REM zwar selbst auf, SKEL_RESULTS wird hier aber zum Oeffnen der SVG gebraucht.
call "%SPS_SKEL_HOME%\bin\setenv.bat" >nul

REM Eingabe-CSV: Dateiname wird in DXFM_RESULTS gesucht, Pfade bleiben
set "CSV=%~1"
if "%CSV%"=="" set "CSV=export.csv"
if exist "%DXFM_RESULTS%\%CSV%" set "CSV=%DXFM_RESULTS%\%CSV%"
if not exist "%CSV%" (
    echo FEHLER: CSV nicht gefunden: %CSV%
    echo         Erst in BricsCAD EXPORTCSV ausfuehren.
    endlocal & exit /b 1
)
for %%F in ("%CSV%") do (
    set "CSV=%%~fF"
    set "SVG=%SKEL_RESULTS%\%%~nF_bbs.svg"
)

REM Darstellungsmodus: all (Default) oder flow
set "MODE=%~2"
if "%MODE%"=="" set "MODE=all"

REM Alte SVG entfernen, damit nie eine veraltete Ansicht geoeffnet wird
if exist "%SVG%" del "%SVG%"

call "%SPS_SKEL_HOME%\bin\material_flow.bat" --file "%CSV%" --show-bbs %MODE% --show-kx
set "RC=%ERRORLEVEL%"

if not exist "%SVG%" (
    echo FEHLER: SVG wurde nicht erzeugt ^(material_flow Exit-Code %RC%^).
    endlocal & exit /b 1
)

echo.
echo Boundingbox-Ansicht: %SVG%
REM Vorschau direkt im Standardprogramm fuer .svg (Browser) oeffnen
start "" "%SVG%"

endlocal & exit /b 0