// ============================================================
// hw_ausgabe.dcl - Ziel der HW-Planung waehlen
// Aufruf ueber hw-ausgabe-waehlen (Lisp/HwPlanung.lsp) vor
// HW_MATERIALFLUSS ("Materialfluss erzeugen") und HW_SYMBOLE
// ("Symbole erzeugen") samt Einzelbefehlen.
//
// Der Knopf "Auswaehlen..." schliesst den Dialog per done_dialog 2
// (getfiled funktioniert nicht aus einem action_tile heraus), danach
// wird der Dialog mit dem gewaehlten Pfad erneut gezeigt.
// ============================================================

hw_ausgabe : dialog {
  label = "HW Planung - Ausgabe";

  : text { key = "aktion"; width = 60; }

  : boxed_radio_column {
    label = "Erzeugen in";
    key = "modus";
    : radio_button {
      key = "aktuell";
      label = "Aktuelle Zeichnung (eigene Layer, fruehere Ausgabe wird ersetzt)";
    }
    : radio_button {
      key = "ergaenzen";
      label = "Bestehende Datei ergaenzen";
    }
    : radio_button {
      key = "neu";
      label = "Neue Datei";
    }
  }

  : boxed_column {
    label = "Bestehende Datei";
    key = "box_datei";
    : row {
      : edit_box { key = "datei"; edit_width = 48; }
      : button { key = "waehlen"; label = "Auswaehlen..."; fixed_width = true; }
    }
  }

  : boxed_column {
    label = "Neue Datei";
    key = "box_neu";
    : edit_box { key = "name"; label = "Name:"; edit_width = 40; }
    : text { key = "ordner"; width = 60; }
  }

  errtile;
  ok_cancel;
}