@echo off
REM ================================================================
REM SPS_SKEL - FB_Main-Geruest als SCL erzeugen
REM ================================================================
REM Aufruf:
REM   bin\scl_skeleton.bat
REM   bin\scl_skeleton.bat --json mubea_tro.json
REM   bin\scl_skeleton.bat --json mubea_tro.json --out FB_Main.scl
REM
REM Die JSON-Datei wird in %SKEL_RESULTS% gesucht, die SCL-Datei wird
REM ebenfalls dort abgelegt.
REM
REM Vorstufe: bin\tro_flow.bat --file <name>.csv --json (CSV -> TRO-JSON)
REM ================================================================

setlocal

REM Umgebung setzen (SKEL_DATA, SKEL_RESULTS, SKEL_LIB, PYTHONPATH ...)
call "%~dp0setenv.bat" >nul

REM Virtuelle Umgebung nutzen, falls vorhanden (pydantic wird benoetigt)
if exist "%SPS_SKEL%\.venv\Scripts\activate.bat" (
    call "%SPS_SKEL%\.venv\Scripts\activate.bat"
)

REM Python-Interpreter bestimmen (py-Launcher bevorzugt, sonst python)
set "PY=py"
py --version >nul 2>&1 || set "PY=python"

"%PY%" "%SKEL_LIB%\scl_skeleton.py" %*
set "RC=%ERRORLEVEL%"

endlocal & exit /b %RC%